122 lines
5 KiB
C++
122 lines
5 KiB
C++
// Copyright 2025 Espressif Systems (Shanghai) PTE LTD
|
|
//
|
|
// Licensed under the Apache License, Version 2.0 (the "License");
|
|
// you may not use this file except in compliance with the License.
|
|
// You may obtain a copy of the License at
|
|
|
|
// http://www.apache.org/licenses/LICENSE-2.0
|
|
//
|
|
// Unless required by applicable law or agreed to in writing, software
|
|
// distributed under the License is distributed on an "AS IS" BASIS,
|
|
// WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
|
|
// See the License for the specific language governing permissions and
|
|
// limitations under the License.
|
|
|
|
// Matter Manager
|
|
#include <Matter.h>
|
|
#if !CONFIG_ENABLE_CHIPOBLE
|
|
// if the device can be commissioned using BLE, WiFi is not used - save flash space
|
|
#include <WiFi.h>
|
|
#endif
|
|
|
|
// List of Matter Endpoints for this Node
|
|
// Generic Switch Endpoint - works as a smart button with a single click
|
|
MatterGenericSwitch SmartButton;
|
|
|
|
// CONFIG_ENABLE_CHIPOBLE is enabled when BLE is used to commission the Matter Network
|
|
#if !CONFIG_ENABLE_CHIPOBLE
|
|
// WiFi is manually set and started
|
|
const char *ssid = "your-ssid"; // Change this to your WiFi SSID
|
|
const char *password = "your-password"; // Change this to your WiFi password
|
|
#endif
|
|
|
|
// set your board USER BUTTON pin here
|
|
const uint8_t buttonPin = BOOT_PIN; // Set your pin here. Using BOOT Button.
|
|
|
|
// Button control
|
|
uint32_t button_time_stamp = 0; // debouncing control
|
|
bool button_state = false; // false = released | true = pressed
|
|
const uint32_t debouceTime = 250; // button debouncing time (ms)
|
|
const uint32_t decommissioningTimeout = 5000; // keep the button pressed for 5s, or longer, to decommission
|
|
|
|
void setup() {
|
|
// Initialize the USER BUTTON (Boot button) GPIO that will act as a smart button or to decommission the Matter Node
|
|
pinMode(buttonPin, INPUT_PULLUP);
|
|
|
|
Serial.begin(115200);
|
|
|
|
// CONFIG_ENABLE_CHIPOBLE is enabled when BLE is used to commission the Matter Network
|
|
#if !CONFIG_ENABLE_CHIPOBLE
|
|
// We start by connecting to a WiFi network
|
|
Serial.print("Connecting to ");
|
|
Serial.println(ssid);
|
|
|
|
// Manually connect to WiFi
|
|
WiFi.begin(ssid, password);
|
|
// Wait for connection
|
|
while (WiFi.status() != WL_CONNECTED) {
|
|
delay(500);
|
|
Serial.print(".");
|
|
}
|
|
Serial.println("\r\nWiFi connected");
|
|
Serial.println("IP address: ");
|
|
Serial.println(WiFi.localIP());
|
|
delay(500);
|
|
#endif
|
|
|
|
// Initialize the Matter EndPoint
|
|
SmartButton.begin();
|
|
|
|
// Matter beginning - Last step, after all EndPoints are initialized
|
|
Matter.begin();
|
|
// This may be a restart of a already commissioned Matter accessory
|
|
if (Matter.isDeviceCommissioned()) {
|
|
Serial.println("Matter Node is commissioned and connected to the network. Ready for use.");
|
|
}
|
|
}
|
|
|
|
void loop() {
|
|
// Check Matter Accessory Commissioning state, which may change during execution of loop()
|
|
if (!Matter.isDeviceCommissioned()) {
|
|
Serial.println("");
|
|
Serial.println("Matter Node is not commissioned yet.");
|
|
Serial.println("Initiate the device discovery in your Matter environment.");
|
|
Serial.println("Commission it to your Matter hub with the manual pairing code or QR code");
|
|
Serial.printf("Manual pairing code: %s\r\n", Matter.getManualPairingCode().c_str());
|
|
Serial.printf("QR code URL: %s\r\n", Matter.getOnboardingQRCodeUrl().c_str());
|
|
// waits for Matter Generic Switch Commissioning.
|
|
uint32_t timeCount = 0;
|
|
while (!Matter.isDeviceCommissioned()) {
|
|
delay(100);
|
|
if ((timeCount++ % 50) == 0) { // 50*100ms = 5 sec
|
|
Serial.println("Matter Node not commissioned yet. Waiting for commissioning.");
|
|
}
|
|
}
|
|
Serial.println("Matter Node is commissioned and connected to the network. Ready for use.");
|
|
}
|
|
|
|
// A builtin button is used to trigger a command to the Matter Controller
|
|
// Check if the button has been pressed
|
|
if (digitalRead(buttonPin) == LOW && !button_state) {
|
|
// deals with button debouncing
|
|
button_time_stamp = millis(); // record the time while the button is pressed.
|
|
button_state = true; // pressed.
|
|
}
|
|
|
|
// Onboard User Button is used as a smart button or to decommission it
|
|
uint32_t time_diff = millis() - button_time_stamp;
|
|
if (button_state && time_diff > debouceTime && digitalRead(buttonPin) == HIGH) {
|
|
button_state = false; // released
|
|
// builtin button is released - send a click event to the Matter Controller
|
|
Serial.println("User button released. Sending Click to the Matter Controller!");
|
|
// Matter Controller will receive an event and, if programmed, it will trigger an action
|
|
SmartButton.click();
|
|
}
|
|
|
|
// Onboard User Button is kept pressed for longer than 5 seconds in order to decommission matter node
|
|
if (button_state && time_diff > decommissioningTimeout) {
|
|
Serial.println("Decommissioning the Generic Switch Matter Accessory. It shall be commissioned again.");
|
|
Matter.decommission();
|
|
button_time_stamp = millis(); // avoid running decommissining again, reboot takes a second or so
|
|
}
|
|
}
|